
 1000  *SAVE S.DIFFERENCES
 1010  *--------------------------------
 1020  *      DISPLAY MAP OF DIFFERENCES
 1030  *      IN TWO MEMORY REGIONS
 1040  *
 1050  *      ADR1<ADR2.ADR3^Y
 1060  *
 1070  *--------------------------------
 1080  A1     .EQ $3C,3D
 1090  A4     .EQ $42,43
 1100  *--------------------------------
 1110  MON.NXTA4  .EQ $FCB4
 1120  MON.PRA1   .EQ $FD92
 1130  MON.COUT   .EQ $FDED
 1140  *--------------------------------
 1150  SETUP  LDA #DIFFERENCES
 1160         STA $3F9
 1170         LDA /DIFFERENCES
 1180         STA $3FA
 1190         RTS
 1200  *--------------------------------
 1210  DIFFERENCES
 1220         JSR MON.PRA1      PRINT CR, ADDRESS AND "-"
 1230  .1     LDY #0            COMPARE TWO BYTES
 1240         LDA (A1),Y
 1250         CMP (A4),Y
 1260         BEQ .2            SAME, SELECT FIRST CHAR
 1270         INY               DIFF, SELECT 2ND CHAR
 1280  .2     LDA CHARS,Y       GET DISPLAY CHAR
 1290         JSR MON.COUT      PRINT SAME OR DIFF CHAR
 1300         JSR MON.NXTA4     NEXT ADDRESS AND TEST
 1310         BCS .3            ...FINISHED
 1320         LDA A1            CHECK FOR FULL LINE
 1330         AND #$1F          OF 32
 1340         BNE .1            ...FULL YET
 1350         BEQ DIFFERENCES   ...FULL
 1360  .3     RTS
 1370  *--------------------------------
 1380  CHARS  .AS -/.*/         SAME AND DIFF CHARS
 1390  *--------------------------------

